29 - LIN - Curve Fitting - Kurvenanpassung

Post Reply
Peet
Posts: 257
Joined: Tue Sep 29, 2020 12:01 am
Location: Germany

29 - LIN - Curve Fitting - Kurvenanpassung

Post by Peet »

Code: Select all

LBL "LIN"
SF 27
"LIN*EX*LG*PT"
PROMPT
LBL F
5
"LIN"
GTO 13
LBL G
6
"EX"
GTO 13
LBL H
7
"LG"
GTO 13
LBL I
8
"PT"
LBL 13
CLRG
SF 21
STO 00
SREG 10
CLS
BEEP
PROMPT
LBL a
X<>Y
XEQ IND 00
S- 
STOP
LBL A
X<>Y
XEQ IND 00
S+
STOP
LBL 07
LN
RTN
LBL 08
LN
LBL 06
X<>Y
LN
X<>Y
RTN
LBL B
RCL 15
RCL 11
RCL 10
RCL 10
XEQ 09
STO 03
RCL 12
RCL 11
RCL 10
RCL 14
XEQ 09
RCL 03
/
STO 04
XEQ IND 00
STO 06
RCL 15
RCL 14
RCL 10
RCL 12
XEQ 09
RCL 03
/
STO 05
LBL 03
RCL 04
RCL 12
*
RCL 05
RCL 14
*
+
RCL 12
X^2
RCL 15
/
STO 09
-
RCL 13
RCL 09
-
/
"R2"
XEQ 10
RCL 06
"A"
XEQ 10
RCL 05
"B"
GTO 01
LBL 06
LBL 08
E^X
LBL 05
LBL 07
RTN
LBL 09
*
STO 07
RDN
*
RCL 07
-
RTN
LBL 00
"Y"
LBL 01
"|-="
ARCL X
AVIEW
FS? 55
STOP
GTO IND 00
LBL 08
RCL 05
Y^X
GTO 09
LBL 06
RCL 05
*
E^X
LBL 09
RCL 06
*
GTO 00
LBL 07
LN
LBL 05
RCL 05
*
RCL 06
+
GTO 00
LBL 10
"|-="
ARCL X
AVIEW
END
HP41 Standard Applications (modified version)
Changes (among others): Local label instead of global, operation

Usage:

F: LIN y=a+bx
G: EX y=ae^bx
H: LG y=a+b*ln(x)
I: PT y=ax^b

a: Correction
A: Input
B: Calculate R^2 & a and b
R/S: a
R/S: b
x R/S: y.
x R/S: y.
etc.
Attachments
29_LIN_Kurve.raw
(218 Bytes) Downloaded 233 times
My programmable calculators - former: CBM PR100, HP41CV, HP28S, HP11C - current: HP48G(256kB), HP35S, Prime, DM41X, DM42
Post Reply