Changes (amongst others): Local label instead of Key-Asignment, fixed starting capital of 5000, specification of the playing time/rounds.
Usage (CLRG may be necessary):
ROUNDS? (playing time) e.g. 15 R/S
H (DL) - Bet e.g. 500 <H>
Bank draws 2 and shows 1 card, the first two are drawn for the player
A (HT) - Card
B (S) - Pass
Local vs (Standard Applications) global label:
LBL H - DL
LBL A - HT
LBL B - S
LBL 90 - CRD
LBL 10 - SH
LBL 33 - P
Register usage:
R21: 5000 (start capital)
R26 Rounds remaining (GAME TIME)
R18 card value player
R25 card value bank
Code: Select all
LBL "BJC"
SF 27
CF 29
0
STO 20
STO 14
"ROUNDS?"
PROMPT
1
+
STO 26
5 E3
STO 21
FIX 0
GTO 09
LBL 33
"A PUSH"
AVIEW
ST* 20
RTN
LBL 90
CLA
ASTO 19
1
STO 15
XROM 26,36 ;TRNG or XEQ "ZZ"
RCL 14
*
INT
1
+
LBL 02
RCL IND 15
X>Y?
GTO 03
-
ISG 15
LBL 99
GTO 02
LBL 03
DSE IND 15
LBL 99
DSE 14
12
RCL 14
X>Y?
GTO 04
XEQ 10
LBL 04
RCL 15
STO 16
10
X<=Y?
GTO 00
X<>Y
STO 16
1
X=Y?
GTO 11
CLA
ARCL Y
GTO 01
LBL 00
STO 16
CLX
10
X=Y?
GTO 13
1
+
X=Y?
GTO 71
1
+
X=Y?
GTO 70
"K"
GTO 01
LBL 11
"A"
CF 07
GTO 01
LBL 70
"Q"
GTO 01
LBL 71
"J"
GTO 01
LBL 13
"X"
LBL 01
ASTO 19
RCL 16
RTN
LBL 10
"SHUFFLING"
AVIEW
1.013
ENTER
8
LBL 14
STO IND Y
ISG Y
GTO 14
104
STO 14
CLD
RTN
LBL H
0
STO 20
RDN
CF 09
SF 07
ABS
INT
FS?C 22
STO 22
RCL 22
RCL 21
X<>Y
X>Y?
GTO 09
STO 20
SF 06
CLA
ASTO 18
ASTO 25
XEQ 90
RCL 15
STO 17
XEQ 90
STO 23
CF 08
FS? 07
SF 08
CLA
ARCL 19
ARCL 25
ASTO 25
"BANK SHOWS "
ARCL 25
AVIEW
PSE
SF 07
0
STO 24
XEQ 90
XEQ 91
XEQ 90
XEQ 91
RCL 24
10
FS? 07
CLX
+
21
X#Y?
SF 09
FS? 09
RTN
21.5
STO 24
1.5
ST* 20
"BLACKJACK"
TONE 7
TONE 8
TONE 9
AVIEW
BEEP
TONE 9
TONE 8
TONE 6
LBL B
CF 06
FS? 07
GTO 05
11
RCL 24
X>Y?
GTO 05
10
ST+ 24
LBL 05
CF 07
FS? 08
SF 07
RCL 17
STO 15
XEQ 04
XEQ 80
FS? 07
GTO 07
11
RCL 23
X#Y?
GTO 07
21.5
STO 23
"B:BLACKJACK"
AVIEW
GTO 07
LBL 06
XEQ 90
XEQ 80
LBL 07
FS? 06
GTO 09
FC? 09
GTO 08
RCL 23
17
X<=Y?
GTO 08
FS? 07
GTO 06
11
RCL 23
X>Y?
GTO 06
7
X>Y?
GTO 06
10
ST+ 23
LBL 08
21.5
RCL 23
X>Y?
XEQ 12
RCL 24
-
X=0?
XEQ 33
X>0?
SF 06
LBL 09
RCL 20
FS? 06
CHS
FS? 06
TONE 0
FC? 06
TONE 9
ST+ 21
"CASH $"
ARCL 21
AVIEW
RCL 21
DSE 26
X=0?
GTO 32
RTN
LBL A
XEQ 90
XEQ 91
RCL 24
21.5
X>Y?
RTN
"YOU BUST"
TONE 2
TONE 2
AVIEW
GTO 05
LBL 12
"BUST"
TONE 9
TONE 8
AVIEW
0
RTN
LBL 91
ST+ 24
CLA
ARCL 18
ARCL 19
ASTO 18
"PLAYER: "
ARCL 18
AVIEW
RTN
LBL 80
ST+ 23
CLA
ARCL 25
ARCL 19
ASTO 25
"BANK: "
ARCL 25
AVIEW
PSE
RTN
LBL 32
BEEP
"GAME OVER"
AVIEW
PSE
TONE 9
SF 29
CF 27
FIX 4
END