Photo developing timer

Contributions to this software library are always welcome. Please ensure that you post program listings rather than .raw files. They give a reasonable idea of what your program does without having to load them into a DM42 and you can also include comments in your code. Check out the following link for a decoder/encoder: http://www.swissmicros.com/dm42/decoder/

You can then copy/paste the listing and post it in "code" tags.
Post Reply
michel.lample
Posts: 6
Joined: Wed May 03, 2017 3:09 pm

Photo developing timer

Post by michel.lample » Sun Apr 26, 2020 3:24 pm

This program is a timer for the development of photographic films in argentic lab.

It is dedicated to b&w films in 5 stages:
  • PRE (prewash or preheat)
    DEV (development)
    STP (stop bath)
    FIX (fixer)
    WASH (final wash)
The program uses a VARMENU to set the timer values for each stage (in "min, sec").
Then, pressing one of these keys starts the stopwatch from this step (so press PRE to start from the beginning).
At the end of each step, the program launches a few "tones" during the last 10 seconds, then it beeps and asks for confirmation to continue to the next step.
As it uses the internal timer, it is accurate even if sometime, some seconds are not displayed (PSE is too long) !

This program can be easily adapted to color C41 processes just by modifying the VARMENU and the relevant variables names before LBL C.

The registers used by subroutine C (the counter) are :
R03 : the stage-ident to be displayed (eg : "DEV : ")
R00 : the initial time (H.m.s)
R01 : the current time (H.m.s)
R02 : the final time (H.m.s)

The subroutine LBL d displays the current timer in "min,sec" format (eg : "WASH : 0,12 > 10,30" for : washing step, current counter is 0min12sec and ends at 10min30sec)

Well, for me it is a valuable tool: before my old PALM crashed, I used the "Palm-fototimer" program. Today, there is a lot of tools for IOS or Android but... I don't like these machines :-(

Have fun !
Michel

Code: Select all

00 { 273-Byte Prgm }
01▸LBL "PHTIMER"
02 MVAR "PRE"
03 MVAR "DEV"
04 MVAR "STP"
05 MVAR "FIX"
06 MVAR "WASH"
07 VARMENU "PHTIMER"
08 STOP
09 EXITALL
10 ASTO ST X
11 GTO IND ST X
12▸LBL "PRE"
13 "PRE: "
14 ASTO 03
15 RCL "PRE"
16 XEQ C
17▸LBL "DEV"
18 "DEV: "
19 ASTO 03
20 RCL "DEV"
21 XEQ C
22▸LBL "STP"
23 "STOP: "
24 ASTO 03
25 RCL "STP"
26 XEQ C
27▸LBL "FIX"
28 "FIX: "
29 ASTO 03
30 RCL "FIX"
31 XEQ C
32▸LBL "WASH"
33 "WASH: "
34 ASTO 03
35 RCL "WASH"
36 XEQ C
37 RTN
38▸LBL C
39 ARCL ST X
40 TONE 3
41 ├"min Press R/S"
42 AVIEW
43 STOP
44 FIX 02
45 TIME
46 STO 00
47 X<>Y
48 100
49 ÷
50 HMS+
51 STO 02
52▸LBL 00
53 TIME
54 STO 01
55 XEQ d
56 RCL 01
57 RCL 02
58 X≤Y?
59 GTO 01
60 X<>Y
61 HMS-
62 1ᴇ4
63 ×
64 10
65 X<Y?
66 GTO 00
67 TONE 9
68 GTO 00
69▸LBL 01
70 BEEP
71 RTN
72▸LBL d
73 RCL 01
74 RCL 00
75 HMS-
76 100
77 ×
78 CLA
79 ARCL 03
80 ARCL ST X
81 ├" > "
82 RCL 02
83 RCL 00
84 HMS-
85 100
86 ×
87 ARCL ST X
88 AVIEW
89 PSE
90 END
Attachments
PhotoTimer.raw
(276 Bytes) Downloaded 18 times

Post Reply