Page 1 of 1

### psycho wallpaper

Posted: Mon Apr 15, 2019 8:29 pm
Hi,

(if my memory serves me right...)
A long time ago (it was the ATARI800/C64 time) this or a similiar program was printed in one of the home computer
magazines and it was called "Psycho Tapete" (german for "psycho wallpaper)....I think (read: dont know for sure) it
was printed in the "c't", a german computer magazine, which is still available.
I implemented this from my memory...so it may be totally different, but the result looks very similar to the program
"Psycho Tapete"...

What does it? It creates screens like these:
20190415-19111366.bmp (12.31 KiB) Viewed 4756 times
20190415-12000306.bmp (12.31 KiB) Viewed 4756 times
The raw file is in the attachment.
The code is here:

Code: Select all

``````00 { 135-Byte Prgm }
01▸LBL "psyplt"
02 MVAR "GrMod"
03 MVAR "mod"
04 MVAR "fac"
06 STOP
07 EXITALL
08 RCL "mod"
09 STO 02
10 RCL "fac"
11 STO 03
12 RCL "ResY"
13 STO 01
14 SF 25
15▸LBL 00
16 CLV "pltp"
17 RCL "ResX"
18 STO 00
19 1
20 1
21 DIM "pltp"
22 GROW
23 INDEX "pltp"
24 COMPLEX
25 STO× "pltp"
26▸LBL 01
27 RCL 00
28 SIN
29 RCL 01
30 COS
31 ×
32 RCL× 03
33 IP
34 RCL 02
35 MOD
36 X≠0?
37 GTO 02
38 RCL 00
39 RCL 01
40 COMPLEX
41 →
42▸LBL 02
43 DSE 00
44 GTO 01
45 RCL "pltp"
46 PIXEL
47 DSE 01
48 GTO 00
49 END
``````
I am still unsure, what the fastest way is to handle the contents of the complex matrix:
Each row will have a different number of points to plot.
1.) With each row delete the previous matrix create a new 1x1 matrix, complexify it, set grow mode, add points, plot the matrix and so on.
2.) Create a full sized matrix (a complete row), add points and count them, redim the matrix before each PIXEL commmand, reset counter and so on.
3.) Pixel each point
4.) Any other more speedy version anyone?

But in any case: Have fun!

Cheers!
mcc

### Re: psycho wallpaper

Posted: Tue Apr 16, 2019 8:45 am
Hi,

there is a new version. This has one advantage over the previous one: It does not abort with the error of the previous one.

Code: Select all

``````00 { 154-Byte Prgm }
01▸LBL "psyplt"
02 MVAR "GrMod"
03 MVAR "mod"
04 MVAR "fac"
06 STOP
07 EXITALL
08 RCL "mod"
09 STO 02
10 RCL "fac"
11 STO 03
12 RCL "ResY"
13 STO 01
14 0
15 STO 04
16 SF 25
17▸LBL 00
18 CLV "pltp"
19 RCL "ResX"
20 STO 00
21 1
22 DIM "pltp"
23 INDEX "pltp"
24 1
25 COMPLEX
26 STO× "pltp"
27▸LBL 01
28 RCL 00
29 SIN
30 RCL 01
31 COS
32 ×
33 RCL× 03
34 IP
35 RCL 02
36 MOD
37 X≠0?
38 GTO 02
39 RCL 00
40 RCL 01
41 COMPLEX
42 →
43 1
44 STO+ 04
45▸LBL 02
46 DSE 00
47 GTO 01
48 RCL 04
49 1
50 DIM "pltp"
51 RCL "pltp"
52 PIXEL
53 0
54 STO 04
55 DSE 01
56 GTO 00
57 END
``````
An image I made with the program:
20190416-08362390.bmp (12.31 KiB) Viewed 4706 times
The parameters for this image:
mod:2
fac:2000

The program is also attached as a *.raw.zip file.

Have fun!
Cheers!
mcc

### Re: psycho wallpaper

Posted: Mon Apr 29, 2019 7:14 am
Hi mcc,

This is a cute program. I really like it!

Did you also enter 2 for GrMod? You did not mention what you entered for GrMod, but an entry was expected. I tried the following entries and found some interesting images.

GrMod=2, mod=2, fac=2000
GrMod=2, mod=4, fac=4000
GrMod=2, mod=6, fac=6000
GrMod=2, mod=8, fac=8000

As you can tell, I am having fun with this program!

Best,

Bob

### Re: psycho wallpaper

Posted: Thu May 02, 2019 6:04 pm
Hi Bob,

I am happy to hear that this little program has found a friend

Currently I am trying to speed up the processing of the data.
For example, the cos() is calculated much too often. Will see,
when there will be time for this...

The wallpapers I posted are done with GrMod 3.

Have FUN!
Cheers!
Meino

### Re: psycho wallpaper

Posted: Sun May 05, 2019 1:46 pm
Hi,

the program was updated: It is now a little faster.
The output is a tiny bit different. It seems to be a shift by one pixel or such...
I am still searching the reason.

Here is the code:

Code: Select all

``````00 { 182-Byte Prgm }
01▸LBL "psyplt"
02 MVAR "GrMod"
03 MVAR "mod"
04 MVAR "fac"
05 FC? 64
06 GTO 04
07 CLV "mod"
08 CLV "fac"
09 CLV "pltp"
10 CLST
11 GTO 05
12▸LBL 04
14 STOP
15 TIME
16 STO 10
17 EXITALL
18 RCL "mod"
19 STO 02
20 RCL "fac"
21 STO 03
22 RCL "ResX"
23 STO 05
24 RCL "ResY"
25 STO 01
26 0
27 STO 04
28 SF 25
29▸LBL 00
30 CLV "pltp"
31 RCL 05
32 STO 00
33 1
34 DIM "pltp"
35 INDEX "pltp"
36 RCL 01
37 COS
38 RCL× 03
39 STO 04
40▸LBL 01
41 RCL 00
42 SIN
43 RCL× 04
44 IP
45 RCL 02
46 MOD
47 X≠0?
48 GTO 02
49 RCL 00
50 →
51▸LBL 02
52 DSE 00
53 GTO 01
54 RCLIJ
55 DIM "pltp"
56 0
57 RCL 01
58 COMPLEX
59 RCL+ "pltp"
60 PIXEL
61 DSE 01
62 GTO 00
63 TIME
64 STO 11
65 RCL- 10
66 STO 12
67 STOP
68 ATIME
69 AVIEW
70▸LBL 05
71 END``````
The raw file is attached.

...no it is not sorry. I tried it several times and got "HTTP ERROR" (nothing more) as a pop up. Hmmm...
WIll try it later again...

HAVE FUN!

Cheers!
Meino

### Re: psycho wallpaper

Posted: Mon May 06, 2019 7:13 am
mcc wrote:
Sun May 05, 2019 1:46 pm

The raw file is attached.

...no it is not sorry. I tried it several times and got "HTTP ERROR" (nothing more) as a pop up. Hmmm...
WIll try it later again...

HAVE FUN!

Cheers!
Meino
Maybe he fixed it since I just tried it and got the zip file in which was located the raw file. There was no error.

Tom L

### Re: psycho wallpaper

Posted: Mon May 13, 2019 5:55 am
Hi Meino,

I am pleased with the version of the program that I already have. It may not be worthwhile to put a bit of time into modifying the program so that it runs a little faster. I have now run the program with the following inputs. All of them run fine.

GrMod=3, mod=2, fac=2000
GrMod=3, mod=4, fac=4000
GrMod=3, mod=6, fac=6000
GrMod=3, mod=8, fac=8000
GrMod=2, mod=2, fac=2000
GrMod=2, mod=4, fac=4000
GrMod=2, mod=6, fac=6000
GrMod=2, mod=8, fac=8000

There are of course many more inputs that one could use!

Cheers,

Bob

### Re: psycho wallpaper

Posted: Mon May 13, 2019 10:06 pm
Hi Meino,

Thank you for your efforts with writing this program and in also trying to update it to make it run more efficiently!

Cheers,

Bob
___________________________________________________________________________________________________

Hi Meino,

I am pleased with the version of the program that I already have. It may not be worthwhile to put a bit of time into modifying the program so that it runs a little faster. I have now run the program with the following inputs. All of them run fine.

GrMod=3, mod=2, fac=2000
GrMod=3, mod=4, fac=4000
GrMod=3, mod=6, fac=6000
GrMod=3, mod=8, fac=8000
GrMod=2, mod=2, fac=2000
GrMod=2, mod=4, fac=4000
GrMod=2, mod=6, fac=6000
GrMod=2, mod=8, fac=8000

There are of course many more inputs that one could use!

Cheers,

Bob