Multifunction Plots

Contributions to this software library are always welcome. Please ensure that you post program listings rather than .raw files. They give a reasonable idea of what your program does without having to load them into a DM42 and you can also include comments in your code. Check out the following link for a decoder/encoder: http://www.swissmicros.com/dm42/decoder/

You can then copy/paste the listing and post it in "code" tags.
Post Reply
dlachieze
Posts: 140
Joined: Thu May 04, 2017 10:20 am
Location: France

Multifunction Plots

Post by dlachieze » Sun Dec 24, 2017 4:57 pm

Here is the multifunction plots program from the "Programming Examples and Techniques" page 203. With it you can plot up to 3 different functions of the HP82240A/B printer.
I've tested it by printing the example page 211 on my 82240B printer.

Image

Code: Select all

00 { 424-Byte Prgm }
01▸LBL "PLOT3"
02 MVAR "YMIN"
03 MVAR "YMAX"
04 MVAR "AXIS"
05 MVAR "XMIN"
06 MVAR "XMAX"
07 MVAR "XINC"
08▸LBL A
09 VARMENU "PLOT3"
10 CF 34
11 CF 35
12 CLA
13 STOP
14 EXITALL
15 "FCN1"
16 XEQ 07
17 "FCN2"
18 XEQ 07
19 "FCN3"
20 XEQ 07
21 ADV
22 "Plot of:"
23 PRA
24 ADV
25 SF 12
26 RCL "FCN1"
27 XEQ 08
28 RCL "FCN2"
29 XEQ 08
30 RCL "FCN3"
31 XEQ 08
32 ADV
33 CF 12
34 PRV "YMIN"
35 PRV "YMAX"
36 PRV "AXIS"
37 PRV "XMIN"
38 PRV "XMAX"
39 PRV "XINC"
40 ADV
41 "← YMIN"
42 ├"       YMAX →[LF]"
43 PRA
44 130
45 RCL "YMAX"
46 RCL- "YMIN"
47 ÷
48 STO 00
49 RCL "XMIN"
50 STO 01
51▸LBL 00
52 CLLCD
53 FC? 00
54 XEQ 05
55 FC? 01
56 XEQ 06
57 1.016
58 STO 02
59▸LBL 01
60 49.051
61 STO 03
62▸LBL 02
63 "FCN"
64 RCL 03
65 XTOA
66 ASTO ST X
67 RCL IND ST X
68 STR?
69 XEQ 04
70 ISG 03
71 GTO 02
72 RCL "XINC"
73 16
74 ÷
75 STO+ 01
76 RCL "XMAX"
77 RCL 01
78 X>Y?
79 GTO 03
80 ISG 02
81 GTO 01
82 PRLCD
83 GTO 00
84▸LBL 03
85 PRLCD
86 RTN
87 GTO A
88▸LBL 04
89 RCL 01
90 XEQ IND ST Y
91 SF 24
92 RCL- "YMIN"
93 RCL× 00
94 1
95 +
96 CF 24
97 RCL 02
98 X<>Y
99 X>0?
100 PIXEL
101 RTN
102▸LBL 05
103 CF 21
104 CLA
105 ARCL 01
106 AVIEW
107 SF 21
108 RTN
109▸LBL 06
110 1
111 RCL "AXIS"
112 RCL- "YMIN"
113 RCL× 00
114 +/-
115 1
116 -
117 PIXEL
118 +/-
119 2
120 -
121 "×××××"
122 AGRAPH
123 RTN
124▸LBL 07
125 CF 21
126 ASTO ST L
127 CLX
128 AVIEW
129 PSE
130 CLA
131 FS? 55
132 SF 21
133 SF 25
134 RCL IND ST L
135 CF 25
136 STR?
137 ARCL ST X
138 AON
139 CLD
140 STOP
141 AOFF
142 ALENG
143 X≠0?
144 ASTO ST X
145 STO IND ST L
146 RTN
147▸LBL 08
148 CLA
149 STR?
150 ARCL ST X
151 STR?
152 PRA
153 RTN
154 END
plot3.zip
(500 Bytes) Downloaded 59 times
DM42 SN: 00425

Post Reply