Based very loosely on Eddie Shores Dew point program in his blog http://edspi31415.blogspot.no/2016/07/h ... point.html I made a bit more elaborate program.
This one takes three arguments "Wet Bulb", "Dry Bulb" (thermometer) and the barometric pressure to calclulate the relative humidity in percent and the dew point in °C
Enter wet/dry temp in °C and the barometric pressure in mb.
Ex: Tw=22, Td=25, baro=1013, then R/S gives first the RH% (~76,97%), then Dew Point (~20,68°C)
Code: Select all
00 { 236-Byte Prgm }
01▸LBL "RelHum"
02 "WetBulb T"
03 PROMPT
04 STO "Tw"
05 "DryBulb T"
06 PROMPT
07 STO "Td"
08 "Barometer mb"
09 PROMPT
10 STO "P"
11 17.27
12 RCL× "Td"
13 237.3
14 RCL+ "Td"
15 ÷
16 E↑X
17 6.108
18 ×
19 STO "Es"
20 17.27
21 RCL× "Tw"
22 237.3
23 RCL+ "Tw"
24 ÷
25 E↑X
26 6.108
27 ×
28 STO "Ew"
29 115ᴇ-5
30 RCL× "Tw"
31 1
32 +
33 RCL "Td"
34 RCL- "Tw"
35 ×
36 RCL× "P"
37 66ᴇ-5
38 ×
39 +/-
40 RCL+ "Ew"
41 STO "E"
42 RCL "E"
43 RCL "Es"
44 ÷
45 100
46 ×
47 "RH %"
48 ARCL ST X
49 AVIEW
50 STOP
51 RCL "E"
52 6.108
53 ÷
54 LN
55 17.27
56 ÷
57 STO "B"
58 237.3
59 RCL× "B"
60 1
61 RCL- "B"
62 ÷
63 "Dew Point"
64 ARCL ST X
65 AVIEW
66 STOP
67 END